Zum Inhalt springen

Funktionen

Kostenlose VBA-Funktionen zum Kopieren und Einbauen

Alle Funktionen

IstKwGueltig()

Prüft, ob es eine Kalenderwoche in einem Jahr gibt (nach ISO 8601). Die meisten Jahre haben 52 Kalenderwochen, manche 53 – nämlich, wenn der 1. Januar ein Donnerstag ist oder in einem Schaltjahr der 1. Januar ein Mittwoch. Rückgabe: Wahr oder Falsch.


VBA-Code

VBA · 58 Zeilen
Function IstKwGueltig(Jahr As Integer, KW As Integer) As Boolean

'--------------------------------------------------------------------------------------
' Eine VBA-Funktion von Thomas Garhammer - 07.05.2023
'
' access-garhammer.de - individuelle Access-Programmierung und Hilfe bei Problemen
' access-4u.de        - Shop mit fertigen Datenbanken und offenem VBA-Code
' access-home.de      - kostenlose Beispiele, VBA-Funktionen und SQL
' access-help.de      - Hilfe bei defekten Datenbanken, Fehlern und Abstürzen
'--------------------------------------------------------------------------------------
' Prüfen, ob eine KW gültig ist (ISO 8601). Die höchstmögliche Kalenderwoche ist
' die 53. Sie gibt es nur in Jahren, in denen der 1. Januar ein Donnerstag ist,
' oder in Schaltjahren, in denen der 1. Januar ein Mittwoch ist. Normalerweise
' hat ein Jahr 52 Kalenderwochen.
'
' Nach ISO 8601 beginnt eine Kalenderwoche immer montags, und die erste
' Kalenderwoche eines Jahres ist die, in der der 4. Januar liegt (= die Woche
' mit dem ersten Donnerstag).
'
' Aufruf im Direktfenster:
'  ? IstKwGueltig(2024, 53)  - Falsch
'  ? IstKwGueltig(2026, 53)  - Wahr
'  ? IstKwGueltig(2024, 22)  - Wahr
'  ? IstKwGueltig(2024, 0)   - Falsch
'  ? IstKwGueltig(2024, -10) - Falsch
'
' TG - 09.10.2026
' Überarbeitet: Die Anzahl der Kalenderwochen wird jetzt über den Montag der KW 1
' berechnet. DatePart("ww", 31.12.) liefert oft schon die KW 1 des Folgejahres -
' dadurch waren in manchen Jahren fast alle KWs "ungültig".
'---------------------------------------------------------------------------------------

On Error GoTo fehler

Dim Montag1 As Date
Dim MontagNeu As Date
Dim AnzKW As Long

' Montag der KW 1 in diesem und im nächsten Jahr (Woche mit dem 4. Januar)
    Montag1 = DateSerial(Jahr, 1, 4) - Weekday(DateSerial(Jahr, 1, 4), vbMonday) + 1
    MontagNeu = DateSerial(Jahr + 1, 1, 4) - Weekday(DateSerial(Jahr + 1, 1, 4), vbMonday) + 1

' Anzahl der Kalenderwochen (52 oder 53) und Prüfung
    AnzKW = (MontagNeu - Montag1) / 7
    If KW >= 1 And KW <= AnzKW Then
        IstKwGueltig = True
    Else
        IstKwGueltig = False
    End If

ende:
    Exit Function

fehler:
    IstKwGueltig = False
    Resume ende

End Function

Zusätzliche Beschreibung

Die Funktion prüft, ob eine Kalenderwoche in einem bestimmten Jahr existiert. Das ist praktisch, bevor du mit einer eingegebenen KW weiterrechnest – zum Beispiel mit KWNachDatum().

So funktioniert es:

  1. Nach ISO 8601 ist die KW 1 die Woche, in der der 4. Januar liegt. Für das Jahr und das Folgejahr wird jeweils der Montag dieser Woche berechnet.
  2. Der Abstand der beiden Montage in Tagen, geteilt durch 7, ergibt die Anzahl der Kalenderwochen des Jahres: 52 oder 53.
  3. Liegt die KW zwischen 1 und dieser Anzahl, ist sie gültig.

Beispiele im Direktfenster (Strg+G):

  • ? IstKwGueltig(2024, 53) → Falsch
  • ? IstKwGueltig(2026, 53) → Wahr
  • ? IstKwGueltig(2024, 22) → Wahr
  • ? IstKwGueltig(2024, 0) → Falsch

Überarbeitet am 09.10.2026: Die bisherige Version meldete in manchen Jahren fast alle Kalenderwochen als ungültig, weil die eingebaute Funktion DatePart("ww", …) für den 31. Dezember oft die KW 1 des Folgejahres liefert.