Zum Inhalt springen

Funktionen

Kostenlose VBA-Funktionen zum Kopieren und Einbauen

Alle Funktionen

DatensatzNachText()

Diese Funktion liest den per ID angegebenen Datensatz aus der angegebenen Abfrage aus und gibt ihn als Liste formatiert mit Feldnamen und Feldwerten zurück. Zusätzlich wird die Unterfunktion "StringAuffuellen()" von http://www.access-home.de benötigt.


VBA-Code

VBA · 60 Zeilen
Public Function DatensatzNachText(Qry As String, _
                                  IDFeld As String, _
                                  IDWert As Long)

'--------------------------------------------------------------------------------------
' Eine VBA-Funktion von Thomas Garhammer - 07.01.2023
'
' access-garhammer.de - individuelle Access-Programmierung und Hilfe bei Problemen
' access-4u.de        - Shop mit fertigen Datenbanken und offenem VBA-Code
' access-home.de      - kostenlose Beispiele, VBA-Funktionen und SQL
' access-help.de      - Hilfe bei defekten Datenbanken, Fehlern und Abstürzen
'--------------------------------------------------------------------------------------
' Diese Funktion liest den per ID angegebenen Datensatz aus der angegebenen Abfrage aus
' und gibt ihn als Liste formatiert mit Feldnamen und Feldwerten zurück.
' Zusätzlich wird die Unterfunktion "StringAuffuellen()" von http://www.access-home.de 
' benötigt. 
' Wird die Funktion im Direktfenster z.B. auf eine Abfragen mit Basis,
' auf eine Adresstabelle mit 5 Feldern ausgeführt, könnte folgendes Ergebnis 
' zurückgegeben werden: 
' Aufruf im Direktfenster ? DatensatzNachText("qry_Adressen","AdrNr",12)
'---------------------------------------------------------------------------------------

On Error GoTo fehler

Dim Erg As String
Dim db As Database
Dim rs As Recordset
Dim fld As Field
Dim dat As QueryDef
    
' Variablen setzen
    Set db = CurrentDb()
    Set dat = db.QueryDefs(Qry)
    Set rs = db.OpenRecordset("SELECT * FROM [" & Qry & "] " & _
                              "WHERE [" & IDFeld & "]=" & _
                              IDWert & ";", dbOpenSnapshot)
    
' Zellenwerte
    For Each fld In dat.Fields
        If fld.Name <> IDFeld Then
            Erg = Erg & StringAuffuellen(fld.Name, ".", 20) & _
                                         " " & rs(fld.Name) & _
                                         vbCrLf
        End If
    Next fld
    DatensatzNachText = Erg
    
' Variablen zurücksetzen
    Set dat = Nothing
    rs.Close
    db.Close
    
ende:
    Exit Function
    
fehler:
    DatensatzNachText = ""
    Resume ende
    
End Function

Zusätzliche Beschreibung

Dieser Code generiert eine Textrepräsentation eines Datensatzes aus einer Abfrage. Die Felder und ihre Werte werden in eine Zeichenfolge (DatensatzNachText) eingefügt, wobei die Feldnamen mit Punkten aufgefüllt werden. Potenzielle Fehler werden behandelt und die Funktion wird sicher beendet.

  1. Fehlerbehandlung
    Der Befehl On Error GoTo fehler leitet den Ablauf bei einem Fehler zur Fehlerbehandlungsroutine.
  2. Deklaration der Variablen
    Mehrere Variablen (Erg, db, rs, fld, dat) werden deklariert.
  3. Initialisierung der Variablen
    • Die aktuelle Datenbank wird in der Variablen db
    • Die Abfrage (Qry) wird als QueryDef in der Variablen dat gespeichert.
    • Ein Lese-Snapshot (rs) der Abfrage wird geöffnet, wobei der Datensatz anhand des ID-Feldes (IDFeld) und des ID-Wertes (IDWert) gefiltert wird.
  4. Zellenwerte auslesen
    • Eine Schleife (For Each fld In dat.Fields) durchläuft alle Felder der Abfrage.
    • Für jedes Feld, das nicht dem ID-Feld entspricht, wird der Feldname mit Punkten aufgefüllt (StringAuffuellen) und der Feldwert in die Variable Erg eingefügt. Jeder Feldname und -wert wird in einer neuen Zeile (vbCrLf) hinzugefügt.
    • Das Ergebnis wird der Variablen DatensatzNachText
  5. Freigeben der Variablen
    Die Variablen dat, rs und db werden zurückgesetzt und geschlossen.
  6. Beenden der Funktion
    Mit Exit Function wird die Funktion beendet.
  7. Fehlerbehandlungsroutine
    Bei einem Fehler wird DatensatzNachText auf eine leere Zeichenfolge gesetzt und der Programmablauf zur Marke ende weitergeführt.