AccessVersion()
Diese Funktion gibt die Access-Versionsnummer in einer Meldung aus. In der Meldung wird die interne Nummer, das Build und die tatsächliche Versionsnummer angezeigt.
Zusätzlich wird auch ermittelt, ob es sich um eine Vollversion oder die Runtime von Access handelt.
VBA-Code
VBA · 65 Zeilen
Public Function AccessVersion()
'--------------------------------------------------------------------------------------
' Eine VBA-Funktion von Thomas Garhammer - 03.12.2024
'
' access-garhammer.de - individuelle Access-Programmierung und Hilfe bei Problemen
' access-4u.de - Shop mit fertigen Datenbanken und offenem VBA-Code
' access-home.de - kostenlose Beispiele, VBA-Funktionen und SQL
' access-help.de - Hilfe bei defekten Datenbanken, Fehlern und Abstürzen
'--------------------------------------------------------------------------------------
' Diese Funktion gibt die Access-Versionsnummer in einer Meldung aus. In der Meldung
' wird die interne Nummer, das Build und die tatsächliche Versionsnummer angezeigt.
' Zusätzlich wird auch ermittelt, ob es sich um eine Vollversion oder die Runtime
' von Access handelt.
' Hinweis: Access 2016, 2019, 2021, 2024 und Microsoft 365 melden alle die interne
' Version 16.0 - sie lassen sich nur über das Build unterscheiden.
'
' Überarbeitet 09.10.2026: Text für Version 16.0 (2016 oder neuer) korrigiert
'---------------------------------------------------------------------------------------
On Error GoTo fehler
Dim AccAktuell As String
Dim AccVersion As String
Dim AccArt As String
AccAktuell = Application.Version
Select Case AccAktuell
Case "7.0"
AccVersion = "95"
Case "8.0"
AccVersion = "97"
Case "9.0"
AccVersion = "2000"
Case "10.0"
AccVersion = "2002"
Case "11.0"
AccVersion = "2003"
Case "12.0"
AccVersion = "2007"
Case "14.0"
AccVersion = "2010"
Case "15.0"
AccVersion = "2013"
Case "16.0"
AccVersion = "2016 oder neuer (2019, 2021, 2024 oder Microsoft 365)"
Case Else
AccVersion = "mit der internen Version " & AccAktuell
End Select
If SysCmd(acSysCmdRuntime) = False Then
AccArt = "Vollversion"
Else
AccArt = "Runtime"
End If
MsgBox "Installiert: Access " & AccVersion & vbCrLf & "Interne Version: " & AccAktuell & " - Build " & Application.Build & vbCrLf & "Art: " & AccArt, 64, "Info"
AccessVersion = AccVersion
ende:
Exit Function
fehler:
Resume ende
End FunctionZusätzliche Beschreibung
Der Code zeigt eine Meldung mit der verwendeten Access-Version an, einschließlich interner Versionsnummer und Build-Nummer. Zusätzlich wird angezeigt, ob Access als Vollversion oder als Runtime läuft.
- Fehlerbehandlung
Am Anfang wird festgelegt, dass der Code bei einem Fehler zu einer speziellen Fehlerbehandlungsroutine springt. - Deklaration von Variablen
Drei Zeichenkettenvariablen werden erstellt: eine für die interne Access-Version, eine für die verständlichere Versionsbezeichnung und eine für die Art (Vollversion oder Runtime). - Ermittlung der Access-Version
Die interne Version von Access wird mit Application.Version ermittelt. Je nach Version wird eine verständlichere Bezeichnung (wie "97", "2003" oder "2010") zugewiesen. Access 2016, 2019, 2021, 2024 und Microsoft 365 melden alle die interne Version 16.0, deshalb wird hier "2016 oder neuer" ausgegeben. Die genaue Ausgabe lässt sich nur über die Build-Nummer unterscheiden. - Überprüfung der Laufzeitumgebung
Mit SysCmd(acSysCmdRuntime) wird geprüft, ob Access als Vollversion oder als Runtime ausgeführt wird. Danach wird eine Meldung mit der Version, der internen Versionsnummer, dem Build und der Art angezeigt. Die Versionsbezeichnung wird zusätzlich als Rückgabewert der Funktion zurückgegeben. - Ende und Fehlerbehandlung
Die Funktion wird ordnungsgemäß beendet. Wenn ein Fehler auftritt, springt der Code zur Fehlerbehandlungsroutine und setzt die Ausführung ab der Marke ende fort.